Fushigi Сообщение 19/04/2008 11:00 Копия темы
Флешеры.кодеры – помогите plz с областью видимости Сделал простенький класс imageObj, управляющий картинкой. Обычное растворение, только реализованное через внешний класс caurina.transitions.Tweener , для управляемости процессом. Дак вот, мне нужно чтобы мой imageObj класс диспатчил событие о том, что анимация закончилась. Для этого в классе Tweener предусмотрена возможность вызова функции по окончанию анимации. Но как я понял в этой функции другая область видимости, т.е. в ней я не могу получить значения переменных, использованных мною в этом классе, соответственно и диспатчИвент тоже не пашет... Есть же функция Delegate какая-то, но я с ней не работал, может кто объяснить как оно пашет, на уровне чайника ? заранее спасибо /код под катом

код:
import mx.events.EventDispatcher;
import caurina.transitions.Tweener;
class ImageObj {
private var dispatchEvent:Function;
public var addEventListener, removeEventListener:Function;
private var mc:MovieClip;

function ImageObj($mc:MovieClip) {
mc = $mc;
EventDispatcher.initialize(this);
trace("ImageObj created");
}
public function fade() {
trace("ImageObj fade started");
Tweener.addTween(mc,{_alpha:0, delay:2, time:4, transition:"easeInOutCubic", onComplete:onFadeComplete});
}
function onFadeComplete() {
trace("onFadeComlete called");
dispatchEvent({type:'onFadeComplete'});
}
}

games4you Сообщение 19/04/2008 12:04 Копия темы

games4you Сообщение 19/04/2008 12:07 Копия темы
public function fade() {
trace("ImageObj fade started");
var obj = this;
var onFadeComplete:Function = function() {
trace("onFadeComlete called");
obj.dispatchEvent({type:'onFadeComplete'});
}
Tweener.addTween(mc,{_alpha:0, delay:2, time:4, transition:"easeInOutCubic", onComplete:onFadeComplete});
}

games4you Сообщение 19/04/2008 12:08 Копия темы
попробуй как-то так.

Fushigi Сообщение 19/04/2008 12:14 Копия темы
хехе, хитро, но работает :)) главное не сломать :))) спасибо

games4you Сообщение 19/04/2008 12:55 Копия темы
:)

FlashPro Сообщение 19/04/2008 14:31 Копия темы
Tweener.addTween(mc,{_alpha:0, delay:2, time:4, transition:"easeInOutCubic", onComplete:onFadeComplete});

import mx.utils.Delegate;
Tweener.addTween(mc,{_alpha:0, delay:2, time:4, transition:"easeInOutCubic", onComplete: Delegate.create(this, onFadeComplete) });

Fushigi Сообщение 19/04/2008 15:09 Копия темы
Воот что я и предполагал :)) спасибо большое